ブログタイトルを「FX自動売買システム開発部」から「autoFX」に変更しました!

ダブルボリューム・マーケットトップ戦略のEAを作成してみる(2)

「コナーズの短期売買実践」のトレード戦略のEA化【第1弾】Part2

前回の記事で書いた仕掛け及び手仕舞い条件では、ロジックをプログラム化し難いことがプログラミング中に分かったため、以下の条件に変更しました。

仕掛け条件(ショート専用)

  • 1本前のローソク足の高値が、過去60本(日足の場合、過去3ヶ月に相当)の高値を更新
  • 1本前のローソク足の出来高が、過去15本の平均出来高の2倍以上
  • 1本前のローソク足、今の足、次の足のいずれかで終値が、始値より下に位置している
  • 上記条件が全て成立した場合、次のローソク足の始値でショートエントリー

手仕舞い条件

  • トレイリングストップ(利食い)
  • エントリー時のローソク足の1本前のローソク足の高値に最初のSLを置く(損切り)

「変更しちゃっていいの?」という声が聞こえてきそうですが、私は良いと思っています。まずはざっくりと作ってテストしてみて、脈がありそうだと感じたら、その時に改めて真剣にロジックの設計を見直します。100%の完成度を実現するのが3日必要で、80%の完成度なら1日で良いなら、まずは後者を選ぶわけです。モノづくりってそういうもんです。大体どんなものも試作機から作りますでしょ?

話が逸れました。では、早速動かしてみましょう。バックテストは以下の条件で実施しました。

  • 対象EA:DoubleVolumeMarketTop
  • 通貨ペア:EURUSD
  • ローソク足の種類:日足
  • モデル:全ティック
  • スプレッド:3pips固定
  • バックテスト期間:2008/1/1~2016/7/5
  • ヒストリカルデータ:Dukascopy社のJForexからダウンロードした1分足
  • 初期口座残高:10,000ドル
  • ロット数:0.01固定

結果はこちらです。

DoubleVolumeMarketTopのトレード結果(グラフ)

DoubleVolumeMarketTopのトレード結果(チャート)

元々この手法は日足で紹介されていたので、日足で試してみたのですが、なんと約8年で1回しか条件成立していないではないですか!

試しに1時間足とかで試してみたら、それなりにエントリーがありましたし、条件通り動作していましたので、プログラムは問題ないようです(ちなみに、見事な右肩下がりでしたが)。

見るべきポイントはオレンジ色の枠で囲っていますので、そこを重点的にご注目いただければ幸いです。上記の仕掛け条件と手仕舞い条件をきちんと満たしていることが分かると思います。

このトレード戦略は大量の通貨ペアを同時にウォッチして、条件成立の確率を上げないと使えなそうですね。

それと、これは初めから分かっていたことですが、MT4で取得できる出来高はいわゆる取引量ではなくティック数なので、コナーズ氏の想定していたものとは違います。これも上手く機能しない原因の1つでしょう。

「じゃあ何でこんなものを作ってみようと思ったのか?」ですって?それは、あれです。出来高のVolume()を一度使ってみたかったんです(笑)

DoubleVolumeMarketTop.mq4のコードを公開しますので、良かったら参考になさってください。「1本前のローソク足、今の足、次の足のいずれかで」という部分は他のEAを作成する際に役に立ちそうな気がします。

DoubleVolumeMarketTop.mq4

//+------------------------------------------------------------------+
//|                                        DoubleVolumeMarketTop.mq4 |
//|                                     Copyright (c) 2016, りゅーき |
//|                                            https://autofx100.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright (c) 2016, りゅーき"
#property link      "https://autofx100.com/"
#property version   "1.00"

//+------------------------------------------------------------------+
//| ライブラリ                                                       |
//+------------------------------------------------------------------+
#include <stderror.mqh>
#include <stdlib.mqh>
#include <WinUser32.mqh>
#include <Original/Application.mqh>
#include <Original/Basic.mqh>
#include <Original/DateAndTime.mqh>
#include <Original/LotSizing.mqh>
#include <Original/OrderHandle.mqh>
#include <Original/OrderReliable.mqh>

//+------------------------------------------------------------------+
//| EAパラメータ設定情報                                             |
//+------------------------------------------------------------------+
extern string Note01       = "=== General ==================================================";
extern int    MagicNumber  = 7777777;
extern int    SlippagePips = 5;
extern string Comments     = "";
extern double FixLotSize   = 0.01;

extern string Note02       = "=== Entry ====================================================";
extern int    LongPeriod   = 60;
extern int    ShortPeriod  = 15;
extern double Times        = 2.0;

extern string Note03       = "=== Exit =====================================================";
extern string Note03_1     = "--- Trailing Stop ---------------------------------------------";
extern double TS_StartPips = 15.0;
extern double TS_StopPips  = 10.0;

//+------------------------------------------------------------------+
//| グローバル変数                                                   |
//+------------------------------------------------------------------+
// 共通
double gPipsPoint     = 0.0;
int    gSlippage      = 0;
color  gArrowColor[6] = {Blue, Red, Blue, Red, Blue, Red}; //BUY: Blue, SELL: Red
int    gPrvBars       = 0;

int    gBars          = 0;

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
{
  gPipsPoint = currencyUnitPerPips(Symbol());
  gSlippage = getSlippage(Symbol(), SlippagePips);

  gPrvBars = Bars;

  return(INIT_SUCCEEDED);
}

//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
}

//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
{
  int currentBars = Bars;

  // -----------------------------------------------------------------
  // 手仕舞い
  // -----------------------------------------------------------------
  trailingStopGeneral(MagicNumber, TS_StartPips, TS_StopPips);

  // -----------------------------------------------------------------
  // 仕掛けフィルター
  // -----------------------------------------------------------------
  // 新しい足を生成した時ではない場合は、スキップ
  if(currentBars == gPrvBars){
    gPrvBars = currentBars;
    return;
  }

  // -----------------------------------------------------------------
  // 仕掛け
  // -----------------------------------------------------------------
  // ①1本前のローソク足の高値が、過去60本(日足の場合、過去3ヶ月に相当)の高値を更新
  double latestHigh   = NormalizeDouble(High[1], Digits);
  double longTermHigh = NormalizeDouble(High[iHighest(NULL, 0, MODE_HIGH, LongPeriod, 2)], Digits);

  bool flg1 = false;

  if(latestHigh >= longTermHigh){
    flg1 = true;
  }

  // ②1本前のローソク足の出来高が、過去15本の平均出来高の2倍以上
  double avgVolume = 0.0;

  for(int i = 2; i <= ShortPeriod + 1; i++){
    avgVolume += Volume[i];
  }

  avgVolume = avgVolume / (double)ShortPeriod;

  bool flg2 = false;

  if(Volume[1] >= avgVolume * Times){
    flg2 = true;
  }

  if(gBars == 0 && flg1 && flg2){
    gBars = currentBars;
  }

  // ③1本前のローソク足、今の足、次の足のいずれかで終値が、始値より下に位置している
  bool flg3 = false;

  if(currentBars <= gBars + 2){
    if(Close[1] < Open[1]){
      flg3 = true;
      double sl = NormalizeDouble(High[1], Digits);
    }
  }else{
    gBars = 0;
  }


  if(flg3){
    // ショートのみのエントリー
    int ticket = orderSendReliable(Symbol(), OP_SELL, FixLotSize, Bid, gSlippage, sl, 0, Comments, MagicNumber, 0, gArrowColor[OP_SELL]);
    gBars = 0;
  }

  gPrvBars = currentBars;
}

MQL4プログラミングの最新記事8件

>完全放ったらかしEA 「AutoEndlessCatchRange」

完全放ったらかしEA 「AutoEndlessCatchRange」

「本業が忙しい!」「でも資産運用したい!」そんなあなたに最適なEAです。兼業トレーダーの方はチャートを毎日みて分析してトレードする時間はなかなか確保できないものです。トレードは本EAに任せて、本業やプライベートの時間をもっと増やしませんか?元々は自分自身のために開発したEAですので、手抜き無しのガチものです。

CTR IMG